LibreOfficeDev 25.8 Help
Deze categorie bevat de wiskundige functies voor Calc. Wilt u de Functie-Assistent openen, dan kiest u Invoegen - Functie.
Deze functie geeft een aggregatie-resultaat van de berekeningen in het assortiment. U kunt verschillende statistische functies die hieronder staan gebruiken. Met de Aggregaat-functie kunt u verborgen rijen, fouten, SUBTOTAAL en andere statistische functie resultaten weglaten uit de berekening.
Voegt een reeks getallen toe.
Geeft de som van de waarden van de cellen in een bereik die aan meerdere criteria in meerdere bereiken voldoen.
Berekent de absolute waarde van een getal.
ABS(Getal)
Aantal is het getal waarvan de absolute waarde moet worden berekend. De absolute waarde van een getal is zijn waarde zonder het +/- teken.
=ABS(-56) geeft 56 terug.
=ABS(12) geeft 12 terug.
=ABS(0) geeft 0 terug.
Rondt een getal af op een bepaald aantal decimalen.
AFRONDEN(Getal ; Aantal(optioneel))
Geeft Getal afgerond tot Aantal plaatsen achter de komma terug. De functie rondt af naar het dichtstbijzijnde geheel getal als Aantal wordt weggelaten of nul is. De functie rondt af op de dichtstbijzijnde 10, 100, 1000, enzovoort als Aantal negatief is.
Deze functie rond af naar het dichtstbijzijnde getal. Zie ook AFRONDEN.NAARBENEDEN en AFRONDEN.NAAR.BOVEN voor alternatieven.
=AFRONDEN(2,348;2) geeft 2,35 terug.
=AFRONDEN(-32,4834;3) geeft -32,483 terug. Wijzig de opmaak van de cel om alle getallen achter de komma te zien.
=AFRONDEN(2,348;0) geeft 2 terug.
=AFRONDEN(2,5) geeft 3 terug.
=AFRONDEN(987,65;-2) geeft 1000 terug.
Geeft een getal terug dat is afgerond naar het dichtstbijzijnde veelvoud van een ander getal.
AFRONDEN.N.VEELVOUD(Getal; Veelvoud)
Geeft Getal, afgerond tot het dichtstbijzijnde veelvoud van Veelvoud, weer.
Een alternatieve implementatie zou zijn Veelvoudige * AFRONDEN(Getal/Veelvoud).
=AFRONDEN.N.VEELVOUD(15,5;3) geeft 15 terug, omdat 15,5 dichter bij 15 (= 3*5) ligt, dan bij 18 (= 3*6).
=AFRONDEN.N.VEELVOUD(1,4;0,5) geeft 1,5 (= 0,5*3) terug.
Rondt een getal af, weg van nul, tot een bepaalde precisie.
AFRONDEN.NAAR.BOVEN(Getal ; Aantal (optioneel))
Geeft Getal naar boven afgerond (weg van nul) tot op Aantal plaatsen achter de komma. De functie rondt naar boven af op een geheel getal als Aantal wordt weggelaten of nul is. De functie rondt naar boven af op de volgende 10, 100, 1000, enzovoort als Aantal negatief is.
Deze functie rondt af, weg van nul. Zie AFRONDEN.NAAR.BENEDEN en AFRONDEN voor alternatieven.
=AFRONDEN.NAAR.BOVEN(1,1111;2) geeft 1,12 terug.
=AFRONDEN.NAAR.BOVEN(1,2345;1) geeft 1,3 terug.
=AFRONDEN.NAAR.BOVEN(45,67;0) geeft 46 terug.
=AFRONDEN.NAAR.BOVEN(-45,67) geeft -46 terug.
=AFRONDEN.NAAR.BOVEN(987,65;-2) geeft 1000 terug.
Geeft als resultaat een willekeurig getal tussen 0 en 1.
ASELECT()
Deze functie levert een nieuw willekeurig getal steeds als Calc opnieuw berekent. Druk op F9 om handmatig te berekenen.
Om willekeurige getallen te genereren die nooit opnieuw worden berekend:
Kopieer cellen die elk =ASELECT() bevatten en gebruik (met Alles plakken en Formules niet geselecteerd en Getallen geselecteerd).
Gebruik het commando Cellen vullen met willekeurige getallen ().
Gebruik de functie ASELECT.NV() voor niet-volatiele willekeurige getallen.
=ASELECT() geeft een willekeurig getal tussen 0 en 1 terug.
Retourneert een niet-volatiel willekeurig getal tussen 0 en 1.
ASELECT.NV()
De functie maakt een willekeurig niet-volatiel getal. Een niet-volatiele functie wordt niet opnieuw berekent bij nieuwe invoergebeurtenissen. De functie doet bij het drukken op F9 niet opnieuw een berekening, behalve als de cursor op de cel met de functie staat of bij gebruik van het commando (Shift+CommandoCtrl+F9). De functie wordt opnieuw berekend bij het openen van het bestand.
=ASELECT.NV() geeft een niet-volatiel willekeurig getal tussen 0 en 1 terug.
ORG.LIBREOFFICE.RAND.NV
Geeft een willekeurig geheel getal terug uit een gespecificeerd bereik.
ASELECTTUSSEN(Laagste waarde; Hoogste waarde)
Geeft een willekeurig geheel getal terug tussen de gehele getallen Laagste waarde en Hoogste waarde (inclusief beide).
Deze functie levert een nieuw willekeurig getal steeds als Calc opnieuw berekent. Druk op F9 om handmatig te berekenen.
Kopieer cellen die deze functie bevatten en gebruik (met en niet gemarkeerd en gemarkeerd) om willekeurige getallen te genereren die nooit opnieuw berekend worden.
=ASELECTTUSSEN(20;30) geeft een geheel terug tussen 20 en 30.
Retourneert een niet-volatiel willekeurig geheel getal in een opgegeven bereik.
ASELECTTUSSEN.NV(Laagste waarde; Hoogste waarde)
Geeft een niet volatiel willekeurig geheel getal terug binnen een bereik Laagste waarde en Hoogste waarde (beide inclusief). Een niet volatiele functie wordt niet opnieuw berekend bij nieuwe invoer of het indrukken van F9. De functie wordt echter wel opnieuw berekend bij het indrukken van F9 met de cursor op de cel met die functie, bij het openen van het bestand, bij het gebruik van het commando command (Shift+CommandCtrl+F9) en als Boven of Onder opnieuw worden berekend.
=ASELECTTUSSEN.NV(20;30) geeft een niet-volatiel geheel getal tussen 20 en 30 terug.
=ASELECTTUSSEN.NV(A1;30) geeft een niet-volatiel geheel getal terug tussen de waarde van cel A1 en 30. De functie wordt opnieuw berekend wanneer de inhoud van cel A1 verandert.
ORG.LIBREOFFICE.RANDBETWEEN.NV
Berekent de inverse trigonometrische cosinus van een getal.
BOOGCOS(Getal)
Deze functie geeft de inverse trigonometrische cosinus van Getal terug, dat is de hoek (in radialen) waarvan de cosinus Getal is. De teruggegeven hoek ligt tussen 0 en PI.
Gebruik de functie GRADEN om de hoek in graden terug te geven.
=BOOGCOS(-1) geeft 3,14159265358979 terug (PI radialen)
=GRADEN(BOOGCOS(0,5)) geeft 60 terug. De cosinus van 60 graden is 0,5.
Berekent de inverse cosinus hyperbolicus van een getal.
BOOGCOSH(Getal)
Deze functie geeft de inverse cosinus hyperbolicus van Getal terug, dat is het getal waarvan de cosinus hyperbolicus Getal is.
Getal moet groter of gelijk zijn aan 1.
=BOOGCOSH(1) geeft 0 terug.
=BOOGCOSH(COSH(4)) geeft 4 terug.
Geeft de inverse cotangens weer (de boogcotangens) van het opgegeven getal.
BOOGCOT(Getal)
Deze functie geeft de inverse trigonometrische cotangens van Getal terug, dat is de hoek (in radialen) waarvan de cotangens Getal is. De teruggegeven hoek ligt tussen 0 en PI.
Gebruik de functie GRADEN om de hoek in graden terug te geven.
=BOOGCOT(1) geeft 0,785398163397448 terug (PI/4 radialen).
=GRADEN(BOOGCOT(1)) geeft 45 terug. De tangens van 45 graden is 1.
Berekent de inverse cotangens hyperbolicus van een bepaald getal.
BOOGCOTH(Getal)
Deze functie geeft de inverse cotangens hyperbolicus van Getal terug, dat is het getal waarvan de cotangens hyperbolicus Getal is.
Een fout treedt op als Getal tussen, inclusief, -1 en 1 ligt.
=BOOGCOTH(1,1) geeft de inverse cotangens hyperbolicus van 1,1 terug, ongeveer 1,52226.
Berekent de inverse trigonometrische sinus van een getal.
BOOGSIN(Getal)
Deze functie geeft de inverse trigonometrische sinus van Getal terug, dat is de hoek (in radialen) waarvan de sinus Getal is. De teruggegeven hoek ligt tussen -PI/2 en +PI/2.
Gebruik de functie GRADEN om de hoek in graden terug te geven.
=BOOGSIN(0) geeft 0 terug.
=BOOGSIN(1) geeft 1,5707963267949 terug (PI/2 radialen).
=GRADEN(BOOGSIN(0,5)) geeft 30 terug. De sinus van 30 graden is 0,5.
Berekent de inverse sinus hyperbolicus van een getal.
BOOGSINH(Getal)
Deze functie geeft de inverse sinus hyperbolicus van Getal terug, dat is het getal waarvan de sinus hyperbolicus Getal is.
=BOOGSINH(-90) geeft ongeveer -5,1929877 terug.
=BOOGSINH(SINH(4)) geeft 4 terug.
Berekent de inverse trigonometrische tangens van een getal.
BOOGTAN(Getal)
Deze functie geeft de inverse tangens hyperbolicus van Getal terug, dat is het getal waarvan de tangens hyperbolicus Getal is. De teruggegeven hoek ligt tussen -PI/2 en PI/2.
Gebruik de functie GRADEN om de hoek in graden terug te geven.
=BOOGTAN(1) geeft 0,785398163397448 terug (PI/4 radialen).
=GRADEN(BOOGTAN(1)) geeft 45 terug. De tangens van 45 graden is 1.
Retourneert de hoek (in radialen) tussen de x-as en een lijn vanaf de oorsprong tot het punt (GetalX|GetalY).
BOOGTAN2(GetalX; GetalY)
GetalX is de waarde van de x-coördinaat.
Getal is de waarde van de y-coördinaat.
Programmeertalen hebben meestal de tegenovergestelde volgorde van argumenten voor hun BOOGTAN2() functie.
BOOGTAN2 retourneert de hoek (in radialen) tussen de x-as en een lijn van de oorsprong naar het punt (GetalX|GetalY)
=BOOGTAN2(-5;9) retourneert 2,07789 radialen.
Om de hoek in graden te krijgen, past u de functie GRADEN op het resultaat toe.
=GRADEN(BOOGTAN2(12,3;12,3)) geeft 45 toe. De tangens van 45 graden is 1.
LibreOfficeDev geeft 0 als resultaat voor BOOGTAN2(0;0).
De functie kan worden gebruikt voor het converteren van cartesiaanse coördinaten naar polaire coördinaten.
=GRADEN(BOOGTAN2(-8;5)) levert φ = 147,9 graden op
Berekent de inverse tangens hyperbolicus van een getal.
BOOGTANH(Getal)
Deze functie geeft de inverse tangens hyperbolicus van Getal terug, dat is het getal waarvan de tangens hyperbolicus Getal is.
Getal moet voldoen aan de voorwaarde -1 < Getal < 1.
=BOOGTANH(0) geeft 0 terug.
Geeft het aantal combinaties van een deelverzameling van items terug, inclusief herhalingen.
COMBIN.A(Getal 1; Getal 2)
Getal 1 is het aantal items in de verzameling.
Getal 2 is het aantal items waaruit in de verzameling gekozen kan worden.
COMBIN.A geeft het aantal unieke manieren weer om deze items te kiezen, waarbij de volgorde van kiezen niet belangrijk is en herhaling van items is toegestaan. Als er bijvoorbeeld 3 items A, B en C in een verzameling zijn opgenomen, kunt u 2 items kiezen op 6 verschillende manieren, namelijk AA, AB, AC, BB, BC en CC.
COMBIN.A implementeert de formule: (Getal 1+Getal 2-1)! / (Getal 2!(Getal 1-1)!)
=COMBIN.A(3;2) geeft 6 terug.
Geeft het aantal combinaties van elementen zonder herhaling.
COMBINATIES(Getal 1; Getal 2)
Getal 1 is het aantal items in de verzameling.
Getal 2 is het aantal items waaruit in de verzameling gekozen kan worden.
COMBINATIES geeft het aantal manieren terug om deze items te kiezen. Bijvoorbeeld: als er 3 items A, B en C in een verzameling zitten, kunt u 2 items op 3 verschillende manieren kiezen, namelijk AB, AC en BC.
COMBINATIES implementeert de formule: Getal 1!/(Getal 2!*(Getal 1-Getal 2)!)
=COMBINATIES(3;2) geeft 3 terug.
Converteert een valutawaarde uitgedrukt in een van de oude valuta's van 19 lidstaten van de eurozone naar euro's, en vice versa. De omrekening maakt gebruik van de vaste wisselkoersen waartegen de oude valuta's zijn ingevoerd de euro.
We raden aan om de meer flexibele EUROCONVERT-functie te gebruiken voor het omrekenen tussen deze valuta's. CONVERTEREN_OOO is geen gestandaardiseerde functie en is niet overdraagbaar.
CONVERTEREN_OOO(Waarde; Tekst; Tekst)
Waarde is het bedrag van de valuta die moet worden omgerekend.
Tekst is een tekenreeks van drie tekens die de valuta aangeeft waaruit moet worden geconverteerd.
Tekst is een tekenreeks van drie tekens die de valuta aangeeft waarnaar moet worden geconverteerd.
Tekst en Tekst moeten elk een van de volgende waarden hebben: "ATS", "BEF", "CYP", "DEM", "EEK", "ESP", "EUR", "FIM", "FRF", "GRD", " IEP", "ITL", "LTL", "LUF", "LVL", "MTL", "NLG", "PTE", "SIT" en "SKK".
Maar één van Tekst moet gelijk zijn aan "EUR".
=CONVERTEREN_OOO(100;"ATS";"EUR") geeft de eurowaarde van 100 Oostenrijkse schilling terug.
=CONVERTEREN_OOO(100;"EUR";"DEM") zet 100 euro om in Duitse mark.
Bekijk de CONVERTEREN_OOO wiki pagina voor meer over deze functie.
Geeft de cosinus van de opgegeven hoek terug (in radialen).
COS(Getal)
Geeft de (trigonometrische) cosinus van Getal terug, de hoek in radialen.
Gebruik de functie RADIALEN om de cosinus van een hoek in graden weer te geven.
=COS(PI()*2) geeft 1 terug, de cosinus van 2*PI radialen.
=COS(RADIALEN(60)) geeft 0,5 terug, de cosinus van 60 graden.
Geeft de cosecans van de opgegeven hoek (in radialen). De cosecant van een hoek is gelijk aan 1 gedeeld door de sinus van die hoek
COSEC(Hoek)
Geeft de (trigonometrische) cosecans vanHoek, de hoek in radialen.
Gebruik de functie RADIALEN om de cosinus van een hoek in graden weer te geven.
=COSEC(PI()/4)geeft ongeveer 1,4142135624, de inverse van de sinus van PI/4 radialen.
=COSEC(RADIALEN(30)) geeft 2, de cosecans van 30 graden.
Geeft de hyperbolische cosecans van een getal.
COSECH(Hoek)
Geeft de cosecans hyperbolicus van Hoek terug.
=COSECH(1)geeft ongeveer 0,8509181282, de hyperbolische cosecans van 1.
Berekent de cosinus hyperbolicus van een getal.
COSH(Getal)
Geeft de cosinus hyperbolicus van Getal terug.
=COSH(0) geeft 1 terug, de cosinus hyperbolicus van 0.
Geeft de cotangens van de opgegeven hoek terug (in radialen).
COT(Getal)
Geeft de (trigonometrische) cotangens van Getal terug, de hoek in radialen.
Gebruik de functie RADIALEN om de cotangens van een hoek in graden weer te geven.
De cotangens van een hoek is hetzelfde als 1 gedeeld door de tangens van die hoek.
=COT(PI()/4) geeft 1 terug, de cotangens van PI/4 radialen.
=COT(RADIALEN(45)) geeft 1 terug, de cotangens van 45 graden.
Berekent de cotangens hyperbolicus van een gegeven getal (hoek).
COTH(Getal)
Geeft de cotangens hyperbolicus van Getal terug.
=COTH(1) geeft de cotangens hyperbolicus van 1, ongeveer 1,3130.
Converteert tussen oude Europese nationale valuta en van en naar euro's.
EUROCONVERT(Waarde; Van valuta; Naar valuta ;Volledige precisie (optioneel); Driehoeksprecisie (optioneel))
Waarde is het bedrag van de valuta dat moet worden geconverteerd.
Van Valuta naar Valuta zijn de respectievelijke valuta-eenheden waarvan en waarnaar geconverteerd moet worden. Deze moeten tekst zijn, de officiële afkorting voor de valuta (bijvoorbeeld "EUR"). De koersen (weergegeven per Euro) werden vastgesteld door de Europese Commissie.
Volledige_precisie is optioneel. Indien weggelaten of ONWAAR wordt het resultaat afgerond tot achter de komma zoals voor Valuta2. Als Volledige_precisie WAAR is, wordt het resultaat niet afgerond.
Driehoeksprecisie is optioneel. Indien Driehoeksprecisie is opgegeven en >=3 wordt het tussenresultaat van een driehoeksconversie (Van valuta,EUR,Naar valuta) afgerond naar die precisie. Indien Driehoeksprecisie is weggelaten wordt het resultaat niet afgerond. Ook als Naar valuta "EUR" is wordt Driehoeksprecisie gebruikt alsof driehoeksprecisie nodig was en wordt de conversie van EUR naar EUR toegepast..
=EUROCONVERT(100;"ATS";"EUR") converteert 100 Oostenrijkse schilling naar Euro's.
=EUROCONVERT(100;"EUR";"DEM") converteert 100 Euro's naar Duitse marken.
Rondt een positief getal naar boven af naar het volgende even gehele getal en rondt een negatief getal naar beneden af naar het volgende even gehele getal.
EVEN(Getal)
Geeft Getal afgerond naar boven op het volgende gehele getal, weg van nul.
=EVEN(2,3) geeft 4 terug.
=EVEN(2) geeft 2 terug.
=EVEN(0) geeft 0 terug.
=EVEN(-0,5) geeft -2 terug.
Geeft als resultaat e verheven tot de macht van een getal De constante e heeft een waarde van ongeveer 2.71828182845904.
EXP(Getal)
Getal is de macht waartoe e verheven moet worden.
=EXP(1) geeft 2,71828182845904 terug, de wiskundige constantee volgens de nauwkeurigheid van Calc.
Retourneert de faculteit van een niet-negatief geheel getal.
FACULTEIT(Getal)
Retourneert Getal, de faculteit van Getal, berekend als 1*2*3*4* ... * Getal.
Retourneert de fout 'ongeldig argument' als het argument een negatief geheel getal is.
Retourneert de fout #WAARDE! als het argument groter is dan 170, wat resulteert in een te groot geheel getal (ongeveer 7E+306).
=FACULTEIT(0) retourneert per definitie 1.
Als het argument geen geheel getal is, wordt het geconverteerd naar de laagste gehele waarde.
=FACULTEIT(3) geeft 6 terug.
=FACULTEIT(3,8) retourneert 6.
=FACULTEIT(0) geeft 1 terug.
Geeft de grootste gemene deler van twee of meer gehele getallen.
De grootste gemene deler is het positieve grootste gehele getal waardoor elk van de opgegeven gehele getallen zonder restwaarde kan worden gedeeld.
GGD(Geheel getal 1 [; Geheel getal 2 [; … [; Geheel getal 255]]])
=GGD(16;32;24) geeft het resultaat 8, omdat 8 het grootste getal is dat 16, 24 en 32 kan delen zonder een restant.
=GGD(B1:B3) waarbij de cellen B1, B2 en B3 bevatten: 9, 12, 9 geeft 3.
Het resultaat is de grootste gemene deler van een lijst met getallen.
GGD_EXCEL2003(Getal 1 [; Getal 2 [; … [; Getal 255]]])
=GGD_EXCEL2003(5;15;25) geeft 5 terug.
Converteert radialen naar graden.
GRADEN(Getal)
Getal is de hoek in radialen die moet worden geconverteerd naar graden.
=GRADEN(PI()) geeft 180 graden terug.
Rondt een getal naar beneden af op het dichtstbijzijnde gehele getal.
INTEGER(Getal)
Geeft Getal afgerond naar beneden naar het dichtstbijzijnde gehele getal terug.
Negatieve getallen worden afgerond naar het gehele getal daar onder.
=INTEGER(5,7) geeft 5 terug.
=INTEGER(-1,3) geeft -2 terug.
Geeft het kleinste gemene veelvoud van een of meer gehele getallen.
KGV(Geheel getal 1 [; Geheel getal 2 [; … [; Geheel getal 255]]])
Als u de getallen 512, 1024 en 2000 als geheel getal 1, 2 en 3 invoert, dan wordt 128000 teruggegeven.
Het resultaat is het kleinste gemene veelvoud van een lijst met getallen.
KGV_EXCEL2003(Getal 1 [; Getal 2 [; … [; Getal 255]]])
=KGV_EXCEL2003(5;15;25) geeft 75 terug.
Berekent de som van de kwadraten van een reeks getallen.
KWADRATENSOM(Getal 1 [; Getal 2 [; … [; Getal 255]]])
Als u de getallen 2, 3 en 4 als argumenten in Getal 1, 2 en 3 invoert, dan wordt 29 als resultaat weergegeven.
Geeft de natuurlijke logaritme op basis van de constante e van een getal. De constante e heeft een waarde van ongeveer 2,71828182845904.
LN(Getal)
Aantal is de waarde waarvan de natuurlijke logaritme berekend moet worden.
=LN(3) geeft het natuurlijk logaritme van 3 terug (ongeveer 1,0986).
=LN(EXP(321)) geeft 321 terug.
Geeft het logaritme van een getal tot de gespecificeerde basis.
LOG(Getal ; Basis (optioneel))
Aantal is de waarde waarvan het logaritme berekend moet worden.
Basis (optioneel) is de base voor berekening van de logaritme. Indien weggelaten wordt 10 als basis beschouwd.
=LOG(10;3) geeft de logaritme naar de basis 3 van 10 (ongeveer 2,0959).
=LOG(7^4;7) geeft 4 terug.
Geeft de logaritme tot de basis 10 van een getal.
LOG10(Getal)
Geeft de logaritme naar basis 10 van Getal terug.
=LOG10(5) geeft de basis-10 logaritme van 5 (ongeveer 0,69897).
Geeft een getal, verheven tot een bepaalde macht, terug.
MACHT(Basis; Exponent)
Geeft Basis verhoogd met de macht Exponent terug.
Hetzelfde resultaat kan worden bereikt door de exponentiatie-operator ^ te gebruiken: Base^Exponent
=MACHT(0,0) retourneert 1; =MACHT(0,X) rapporteert de fout #GETAL! als exponent X negatief is.
=MACHT(B,X) kan wel of niet een fout #GETAL! geven wanneer B negatief is en X geen geheel getal is.
=MACHT(4;3) geeft 64 terug, wat 4 tot de macht 3 is.
=4^3 geeft ook 4 terug tot de macht 3.
=MACHT(2;-3) geeft 0,125 terug.
=MACHT(-2;1/3) geeft -1,25992104989487 terug.
=MACHT(-2;2/3) geeft de fout #GETAL!.
Geeft de faculteit van de som van de argumenten gedeeld door het product van de faculteiten van de argumenten.
MULTINOMIAAL(Getal 1 [; Getal 2 [; … [; Getal 255]]])
=MULTINOMIAAL(F11:H11) geeft 1260 terug, als F11 tot en met H11 de waarden 2, 3 en 4 bevatten. Dit komt overeen met de formule =(2+3+4)! / (2!*3!*4!)
Rondt een positief getal naar boven af op het dichtstbijzijnde oneven gehele getal en een negatief getal naar beneden naar het dichtstbijzijnde oneven gehele getal.
ONEVEN(Getal)
Geeft Getal afgerond naar boven tot het volgende oneven geheel getal terug, weg van nul.
=ONEVEN(1,2) geeft 3 weer.
=ONEVEN(1) geeft 1 weer.
=ONEVEN(0) geeft 1 terug.
=ONEVEN(-3,1) geeft -5 weer.
Geeft 3,14159265358979 terug, de waarde van de wiskundige constante PI met 14 decimale plaatsen.
PI()
=PI() geeft 3,14159265358979 terug.
Geeft het teken terug van een getal. Geeft 1 terug als het getal positief is, -1 indien negatief en 0 indien nul.
POS.NEG(Getal)
Getal is het getal waarvoor het plus- of minteken vastgesteld moet worden.
=POS.NEG(3,4) geeft 1 terug.
=POS.NEG(-4,5) geeft -1 terug.
Vermenigvuldigt alle getallen die als argumenten zijn gegeven en geeft het product.
PRODUCT(Getal 1 [; Getal 2 [; … [; Getal 255]]])
=PRODUCT(2;3;4) geeft 24 terug.
Geeft het deel van het gehele getal terug van een deling.
QUOTIENT(Teller; Noemer)
Geeft het geheel getal-gedeelte van Teller gedeeld door Noemer weer.
QUOTIENT is equivalent met INTEGER(teller/noemer) voor teller en noemer met hetzelfde teken, behalve dat het fouten met verschillende foutcodes kan geven. Meer in het algemeen is het equivalent met INTEGER(teller/noemer/POS.NEG(teller/noemer))*POS.NEG(teller/noemer).
=QUOTIENT(11;3) geeft 3 terug. De resterende 2 gaan verloren.
Converteert graden naar radialen.
RADIALEN(Getal)
Getal is de hoek in graden die moet worden geconverteerd naar radialen.
=RADIALEN(90) geeft 1,5707963267949 terug, wat PI/2 is naar Calc's nauwkeurigheid.
Geeft het restgetal als het ene gehele getal wordt gedeeld door een ander.
REST(Deeltal; Deler)
Voor argumenten voor gehele getallen geeft deze functie Restgetal modulo Deler, dat is het restgetal als Restgetal wordt gedeeld door Deler.
Deze functie is geïmplementeerd als Restgetal - Deler * INT(Restgetal/Deler) en deze formule geeft het resultaat als de argumenten geen gehele getallen zijn.
=REST(22;3) geeft 1 terug, het restgetal als 22 is gedeeld door 3.
=REST(11,25;2,5) geeft 1,25 terug.
Geeft de snijlijn van de opgegeven hoek (in radialen). De snijlijn van een hoek gelijk aan 1 gedeeld door de cosinus van die hoek
SEC(Hoek)
Geeft de (trigonometrische) secans van Hoek, de hoek in radialen.
Gebruik de functie RADIALEN om de secans van een hoek in graden weer te geven.
=SEC(PI()/4) geeft ongeveer 1.4142135624 terug, het omgekeerde van de cosinus van PI/4 radialen.
=SEC(RADIALEN(60)) geeft 2 terug, de secans van 60 graden.
Geeft de secans hyperbolicus van een getal terug.
SECH(Hoek)
Geeft de secans hyperbolicus van Hoek terug.
=SECH(0) geeft 1 terug, de secans hyperbolicus van 0.
Geeft de sinus van de opgegeven hoek terug (in radialen).
SIN(Getal)
Geeft de (trigonometrische) sinus van Getal terug, de hoek in radialen.
Gebruik de functie RADIALEN om de sinus van een hoek in graden weer te geven.
=SIN(PI()/2) geeft 1 terug, de sinus van PI/2 radialen.
=SIN(RADIALEN(30)) geeft 0,5 terug, de sinus van 30 graden.
Berekent de sinus hyperbolicus van een getal.
SINH(Getal)
Geeft de sinus hyperbolicus van Getal terug.
=SINH(0) geeft 0 terug, de sinus hyperbolicus van 0.
Telt de eerste argumenten van een machtreeks op.
SOM.MACHTREEKS(x;n;m;c) = c1xn + c2xn+m + c3xn+2m + ... + cixn + (i-1)m.
SOM.MACHTREEKS(X; N; M; Coëfficiënten)
X is de invoerwaarde voor de machtreeks.
N is de initiële macht
M is de verhoging waarmee N moet worden verhoogd
Coëfficiënten is een reeks coëfficiënten. Voor elke coëfficiënt wordt de som van de uitgebreid met één sectie.
=SOM.MACHTREEKS(A1; 0; 1; {1; 2; 3}) berekent de waarde van 1+2x+3x2, waarbij x de waarde is in cel A1 . Als A1 1 bevat, geeft de formule 6 terug; als A1 2 bevat, retourneert de formule 17; als A1 3 bevat, retourneert de formule 34; enzovoort.
Bekijk de wikipagina SOM.MACHTREEKS voor meer details over deze functie.
Berekent subtotalen. Als een bereik al subtotalen bevat, worden deze niet gebruikt voor verdere berekeningen. Gebruik deze functie met de AutoFilters om alleen de gefilterde records in aanmerking te nemen.
SUBTOTAAL(Functie; Bereik)
Functie is een getal dat voor een van de volgende functies staat:
| Functie-index (inclusief verborgen waarden) | Functie-index (negeert verborgen waardes) | Functie | 
|---|---|---|
| 1 | 101 | GEMIDDELDE | 
| 2 | 102 | AANTAL | 
| 3 | 103 | AANTALARG | 
| 4 | 104 | MAX | 
| 5 | 105 | MIN | 
| 6 | 106 | PRODUCT | 
| 7 | 107 | STDEV | 
| 8 | 108 | STDEVP | 
| 9 | 109 | SOM | 
| 10 | 110 | VAR | 
| 11 | 111 | VARP | 
Gebruik nummers 1-11 om handmatig verborgen rijen bij te sluiten of 101-111 om ze uit te sluiten; gefilterde cellen zijn altijd uitgesloten.
Bereik is het bereik waarvan de cellen opgenomen zijn.
Je hebt een tabel in het celbereik A1:B6 met een stuklijst voor 10 studenten.
| A | B | |
|---|---|---|
| 1 | ITEM | AANTAL | 
| 2 | Pen | 10 | 
| 3 | Potlood | 10 | 
| 4 | Kladblok | 10 | 
| 5 | Vlakgom | 10 | 
| 6 | Potloodslijper | 10 | 
Stel dat één rij handmatig is verborgen, dan toont de eerste formule de som van de vijf gefilterde cijfers; de tweede, alleen de som van de 4 weergegeven cijfers.
=SUBTOTAAL(9;B2:B6) geeft 50.
=SUBTOTAAL(109;B2:B6) geeft 40.
Geeft de tangens van de opgegeven hoek (in radialen) terug.
TAN(Getal)
Geeft de (trigonometrische) tangens van Getal terug, de hoek in radialen.
Gebruik de functie RADIALEN om de tangens van een hoek in graden terug te geven.
=TAN(PI()/4) geeft 1 terug, de tangens van PI/4 radialen.
=TAN(RADIALEN(45)) geeft 1 terug, de tangens van 45 graden.
Berekent de tangens hyperbolicus van een getal.
TANH(Getal)
Geeft de tangens hyperbolicus van Getal terug.
=TANH(0) geeft 0 terug, de tangens hyperbolicus van 0.
Geeft de positieve vierkantswortel van een getal terug.
WORTEL(Getal)
Geeft de positieve vierkantswortel van Getal.
Getal moet positief zijn.
=WORTEL(16) geeft 4 terug.
=WORTEL(-16) geeft een ongeldig argument-fout.
Geeft de vierkantswortel van (PI maal een getal) terug.
WORTEL.PI(getal)
Geeft de positieve vierkantswortel van (PI vermenigvuldigd met Getal) terug.
Dit komt overeen met WORTEL(PI()*Getal).
=WORTEL.PI(2) geeft de vierkantswortel van (2PI) terug, ongeveer 2,506628.